<数式>の絶対値を返します。
ABS(<数式>)
PRINT ABS(-1.2)
【表示】1.2
<文字式>のキャラクタコードを返します。
ASC(<文字式>)
PRINT ASC("a")
【表示】97
指定した<文字式>がいくつかの文字からなる文字列の場合は、一番最初の文字のキャラクタコードが返されます。文字とキャラクタコードの対応については、キャラクタコード表を参照してください。
CHR$、キャラクタコード表
<数式>の逆正接(アークタンジェント)を計算します。
ATN(<数式>)
PRINT ATN(1)*4
【表示】3.1415926535898
プログラム行の先頭に行番号を自動的に発生させます。
AUTO [<行番号>][,<増分>]
AUTO 1000,100
最初の行番号も番号の増加分も省略できますが、この場合は、自動的に10が採用されます。
例えば、
AUTO
行番号は10を先頭に20、30・・・・・・・・と付けられます。
AUTO 100
行番号は100を先頭に110、120・・・・・・・・と付けられます。
AUTO ,5
行番号は10を先頭に15、20・・・・・・・・と付けられます。
プログラム中にすでに存在する行と同じ行番号が発生した場合には、行番号の後にアスタリスク(*)が表示されます。このとき、何も入力しないでリターンキーを押せば、その行は前の内容のままです。
AUTO機能を中止したいときは、[CTRL]+[C]キーまたは[CTRL]+[STOP]キーを押します。
画面出力に関連するVRAM上のテーブルのアドレスを返します。
BASE(<数式>)
PRINT BASE(10)
カッコ内の数値で指定されたVRAM上のテーブルのアドレスを返します。MSX1では、VDPとしてTMS9918、MSX2ではV9938、MSX2+ではV9958を使っています。
VDP
スピーカーを鳴らします。
BEEP
SET BEEP命令で設定した音色と大きさで、スピーカーを鳴らします。
次のように、PRINT命令でCHR$(7)を実行しても、BEEPと同じ結果が得られます。
PRINT CHR$(7)
コントロールコード表
<数式>を2進数の文字列に変換します。
BIN$(<数式>)
PRINT BIN$(50)
【表示】110010
VAL、OCT$、HEX$
機械語プログラム、または画面データファイルを読み込みます(ロードする)。
BLOAD<ファイルスペック>[
,R][,<オフセット>]
BLOAD "A:DEMO",R
<ファイルスペック>で指定した機械語プログラムファイルをメモリ上にロードします。カセットファイルに対してはファイル名を省略することが出来ますが、ディスクファイルに対しては省略することはできません。<ファイルスペック>の中で<デバイス名>を省略すると現在選択されているディスクドライブ(カレントドライブ)とみなされます。カセットファイルを対象とする場合は"CAS:"とします。
<オフセット>を省略すると機械語プログラムはBSAVEでセーブするときに指定した<開始アドレス>からロードしますが、<オフセット>を指定した場合には、セーブの差異に指定されて開始アドレスに、<オフセット>を加えた番地からロードします。したがって、<オフセット>を付けてロードするプログラムは、リロケータブルな性質を持っていなければなりません。
Rオプションを指定すると、プログラムをロード後、BSAVEで指定しておいた実行開始アドレスから、ただちに実行されます。このとき、既に開かれているファイルがあればファイルは開かれたまま機械語プログラムが実行されます。
Sオプションを指定すると、ディスクファイルの内容がVRAMにロードされます。<オフセット>を省略する場合にはカンマ(,)も省略してください。
BSAVE
機械語プログラム、または画面データを保存(セーブ)します。
BSAVE<ファイルスペック>,<開始アドレス>,<終了アドレス>[ [,<実行開始アドレス>|[,S] ]
BSAVE "B:DEMO",&HA100,&HA2FF
<開始アドレス>から<終了アドレス>までのメモリ上に置かれている機械語プログラムを、<ファイルスペック>で指定したファイルにセーブします。
<ファイルスペック>の中の<デバイス名>を省略した場合、カレントドライブにセーブされます。カセットファイルの場合は"CAS:"としてください。
<実行開始アドレス>を指定しておくと、BLOADでRオプションを指定して、プログラムのロード後に自動的に<実行開始アドレス>から実行させることができます。
Sオプションを指定すると、画面データをディスクファイルとしてセーブすることができます。
拡張ステートメントを呼び出します。
CALL<拡張ステートメント名>[(<引数>[,<引数>・・・])]
拡張ROMカートリッジなどで供給される拡張ステートメントを呼び出します。CALLは_(アンダースコア)で代用することができます。
<文字列>中の全ての文字を全角文字に変換して<文字変数>に代入します。
CALL AKCNV(<文字変数,<文字列>)
10 CALL AKCNV(A$,"ABC漢字イロハ")
20 PRINT A$
【表示】ABC漢字イロハ
半角文字(カタカナ、英数字等)を全角の文字に変換します。もともと全角の文字はそのままです。
漢字ドライバを終了します。
CALL ANK
CALL ANK
漢字モードを終了し、ANKモードとなります。ただし、漢字ドライバ用に確保されたメモリは解放されません。
漢字モードの画面をクリアします。
CALL CLS
CALL CLS
漢字モードでは通常のCLSは使えません。漢字モード以外でもCALL CLSは有効です。
フロッピーディスクをフォーマット(初期化)します。
CALL FORMAT
CALL FORMAT
Disk BASICやMSX-DOSで使用できるように、ディスクを初期化します。実行するとドライブ名をきいてくるので、指定します。間違って既に使用しているディスクをフォーマットしてしまうと、その中のデータは完全に失われてしまいます。十分注意してください。
<文字列>の最初の2バイトを16進4桁のJISコードに変換して<文字変数>に代入します。
CALL JIS(<文字変数>,<文字列>)
10 CALL JIS(A$,"漢字")
20 PRINT A$
【表示】3441
<文字列>中の半角文字に変換できる文字をすべて半角文字に変換して<文字変数>に代入します。
CALL KACNV(<文字変数>,<文字列>)
10 CALL KACNV(A$,"10人のプログラマー")
20 PRINT A$
【表示】10人ノプログラマー
漢字ドライバを起動します。
CALL KANJI[n]
CALL KANJI3
nは0、1、2、3のうちどれか1文字で、漢字フォントとSCREENのインタレースモードを指定します。省略すると0とみなされます。
| モード | 文字の大きさ | 表示文字数 |
| (全角X×Y) | (最大横×縦) |
| KANJI0 | 16×16 | 32×13 |
| KANJI1 | 12×16 | 40×13 |
| KANJI2 | 16×16 | 32×24 |
| KANJI3 | 12×16 | 40×24 |
CALL KANJI(またはCALL KANJI0)はフォントをMSXの標準漢字ROMから取って表示します。
CALL KANJI1はフォントをMSXの標準漢字ROMからとり、横16ドットを12ドットに圧縮して表示します。ただし、松下電器の仕様による12ドットフォントROMがシステムに存在する場合はこれを表示します。
CALL KANJI2はCALL KANJI(またはCALL KANJI0)と同じですが、インタレースモードが使用され縦方向の表示文字数が増加します。
CALL KANJI3はCALL KANJI1と同じですが、インタレースモードが使用され縦方向の表示文字数が増加します。
MSX標準の日本語フロントエンドプロセッサ(以下、MSX-JE)があれば、このステートメントの実行時またはシステムの立ち上げ時に組み込まれます。直接入力モード(ANK)と間接入力モード(漢字)は、[CTRL]+[SPACE]もしくは[GRAPH]+[SELECT]によって切り替えられます。MSX-JEが存在しないときは、単漢字変換機能が使用できます。
MSX起動後の一番最初のCALL KANJIの実行時には注意が必要です。その時点でのHIMEM(CLEAR文による)の設定はキャンセルされ、全ての変数およびソフトウェアスタック(FOR/NEXT、GOSUB/RETURN用)がクリアされます。これは漢字ドライバのワークエリア(もしあればMSX-JEも)を確保する処理が行われるからです。2回目以降の実行は問題なく行われます。
CALL KANJI命令などを実行し、漢字表示ができる状態を「漢字モード」と呼びます。さらに漢字モードでかつSCREEN文で0もしくは1が設定されている状態を「漢字テキストモード」と呼び、漢字モードでかつSCREEN文で2以上の画面モードが設定されている状態を「漢字グラフィックモード」と呼びます。
BASICのコマンド待ちの状態では漢字テキストモードになっており、漢字の入出力が可能です。漢字グラフィックモードではプログラムによる漢字の出力のみが可能です。
漢字モードにおけるWIDTH
■漢字テキストモード
CALL KANJI実行後のWIDTHはANKモードでのWIDTHをもとに、以下のように決定されます。CALL KANJI実行後に直接SCREEN文やWIDTH文で指定することもできます。
1.ANKモードでSCREEN 0を使用していた場合。
| ■ | KANJI0かKANJI2 |
| | ANKモードでのWIDTHの値の4/5が漢字テキストモードでのWIDTHになります。 |
| ■ | KANJI1かKANJI3 |
| | ANKモードでのWIDTHの値がそのまま漢字テキストモードでのWIDTHになります。 |
2.ANKモードでSCREEN 1を使用していた場合。
| ■ | KANJI0かKANJI2 |
| | ANKモードでのWIDTHの値がそのまま漢字テキストモードでのWIDTHになります。 |
| ■ | KANJI1かKANJI3 |
| | ANKモードでのWIDTHの値の5/4が漢字テキストモードでのWIDTHになります。 |
■漢字グラフィックモード
常に表示できる最大に設定されます。
WIDTHによるSCREENモードの選択
| ■ | KANJI0かKANJI2 |
| | WIDTHが26から32の時は256ドットモード(VDPのGRAPHIC 4モード)が、33から64の時は512ドットモード(VDPのGRAPHIC 6モード)が選択されます。 |
| ■ | KANJI1かKANJI3 |
| | WIDTHが26から40の時は256ドットモード(VDPのGRAPHIC 4モード)が、41から80の時は512ドットモード(VDPのGRAPHIC 6モード)が選択されます。 |
<機能>が0なら<文字列>中の半角文字だけを、1なら全角文字だけを抜き出して<文字変数>に代入します。
CALL KEXT(<文字変数>,<文字列>,<機能>)
10 CALL KEXT(A$,"今月ハ良イ天気デス",0)
20 PRINT A$
【表示】ハイデス
漢字を含む文字列を検索します。
CALL KINSTR(<数値変数>[,<数式>],<文字列1>,<文字列2>)
10 CALL KINSTR(A,"A 亜 B","B")
20 PRINT A
【表示】3
<文字列1>の中から<文字列2>を探しだし、見つかればその位置を、見つからなければ0を<数値変数>に代入します。<数式>は探し始める位置を文字数を単位として指定するもので、省略した場合は1とみなされます。
漢字を含む文字列の文字数を返します。
CALL KLEN(<数値変数>,<文字列>[,<機能>])
10 CALL KLEN(A,"今日ハ良イ天気です")
20 PRINT A
【表示】9
<機能>が0(もしくは省略)の時は<文字列>の全体の文字数を、1のときは<文字列>中の半角文字数を、2のときは<文字列>中の全角文字数を<数値変数>に代入します。
漢字を含む文字列の一部を取り出します。
CALL KMID(<文字変数>,<文字列>,<数式1>[,<数式2>])
10 CALL KMID(A$,"今日はヨい天気です",3,3)
20 PRINT A$
【表示】はヨい
<文字列>中の<数式1>番目の文字から<数式2>文字分だけ抜き出して<文字変数>に代入します。<数式2>が省略された場合は<数式1>番目の文字から終わりまで全ての文字が代入されます。
漢字コードに相当する漢字を獲得します。
CALL KNJ(<文字変数>,<文字列>)
10 CALL KNJ(A$,"3441")
20 PRINT A$
【表示】漢
<文字列>で指定される4桁の漢字コードに相当する漢字1文字を<文字変数>に代入します。漢字コードが8000H未満であればJIS、それ以上の場合はシフトJISとみなします。
文字のタイプを調べます。
CALL KTYPE(<数値変数>,<文字列>,<数式>)
10 CALL KTYPE(T,"コレハ漢字",4)
20 PRINT T
【表示】1
<文字列>中の<数式>番目の文字のタイプを<数値変数>に代入します。タイプは、0=半角、1=全角です。
メモリディスクで使うメモリの上限を指定します。
CALL MEMINI(<メモリディスクの上限>)
CALL MEMINI(&H7000)
【表示】27904 bytes allocated
範囲は、0〜&H7FFFです。初期状態では、&H7FFFが指定されています。
CALL MEMINI命令が実行されると、メモリディスクに割り当てられたメモリの量が表示されます。
メモリディスク中のファイル名を表示します。
CALL MFILES
CALL MFILES
メモリディスク内のファイルを削除します。
CALL MKILL(<ファイル名>)
CALL MKILL("SAMPLE")
メモリディスク内のファイル名を付け替えます。
CALL MNAME(<新ファイル名>AS<旧ファイル名>)
CALL MNAME("TEST" AS "TEST.AA")
カラーパレットの初期化または設定を行います。
CALL PALETTE[(<パレット番号>,<赤輝度>,<緑輝度>,<黄輝度>)]
CALL PALETTE(15,4,4,4)
CALL KANJIステートメントにより画面を漢字テキストモードにしたときに、パレットを変更するために使用します。漢字モードでないときでも使用できます。
パラメータをすべて省略した場合は、パレットを初期状態にします。パラメータが指定された場合、<パレット番号>で指定されたパレットを<赤輝度>、<緑輝度>、<青輝度>の色に設定します。なお、パレット番号や各輝度を省略することはできません。
<文字列>の最初の2バイトを16進4桁のシフトJISコードに変換して<文字変数>に代入します。
CALL SJIS(<文字変数>,<文字列>)
10 CALL SJIS(A$,"漢字")
20 PRINT A$
【表示】3441
MSX-DOSを起動します。
CALL SYSTEM
CALL SYSTEM
SYSTEMコマンドを実行すると、DOSに戻る前にすべてのファイルは閉じられ、メモリ中のプログラムやデータは失われます。
この命令が実行できるのは、MSX-DOSからDisk BASICを起動した場合だけです。そうでない場合は、「Illegal function call」エラーになります。
<数式>の値を倍精度実数に変換します。
CDBL(<数式>)
PRINT CDBL(1/3)
【表示】.33333333333333
<数式>のキャラクターコードを持つ文字を返します。
CHR$(<数式>)
PRINT CHR$(65)
【表示】A
<数式>は0〜255の範囲でなければなりません。文字とキャラクターコードの対応についてはキャラクターコード表を参照してください。
ASCキャラクターコード表
<数式>の小数点以下を切り捨てて、実数に変換します。
CINT(<数式>)
PRINT CINT(123.45678)
【表示】123
<数式>の値が-32768〜32767の範囲外のときは、「Overflow」エラーになります。
グラフィック画面に円や楕円を描きます。
CIRCLE[STEP](X,Y),<半径>[,<カラーコード>][,<開始角度>][,<終了角度>][,<比率>]
CIRCLE(128,96),50,1
SCREEN2以上の画面で円を描きます。中心座標はX軸方向に255(SCREEN 6、7では511)、Y軸方向に191(SCREEN 5以降では211)ありますので、その範囲内の数値を指定できます。また、STEPを用いて中心を指定することもできます(STEPを用いた指定の方法についてはLINE命令を参照)。
色を指定すると、その色で円が描かれます。色の指定を省略すると、COLORで指定された前景色が用いられます。
| ■ | 弧と扇形 |
| | CIRCLE(128,96),50,1,3/4*3.14,1/4*3.14 |
| | のように、円の開始角度(3/4*3.14)と終了角度(1/4*3.14)を指定すれば、その範囲の弧が描かれます。それぞれにマイナス記号をつけると、扇形が描かれます。開始角度、終了角度の指定は、-2πから2πの範囲内で行います。 |
| ■ | 楕円 |
| | CIRCLE(128,96),50,1,,,0.8 |
| | のように、最後に比率(0.8)を指定すれば、楕円が描かれます。比率は「垂直方向の半径/水平方向の半径」の値で指定します。値が1より小さいと横に平べったい楕円となり、1より大きいと縦に細長い楕円となります。 |
SCREEN、COLOR
変数の初期化と使用するメモリ領域の大きさを指定します。
CLEAR[<文字列領域の大きさ>[,<メモリの上限>]]
CLEAR 200,&HD000
CLEARを実行すると、すべての変数が初期化され、DEF命令(DEF FN、DEFINT/SGN/DBL/STR)の定義は無効になります。初期化されると、数値変数は0に、文字変数はヌル(何も文字が代入されていない状態)になります。
また、
CLEAR 300,&HD000
のような指定では、変数の初期化のほかに、文字変数の内容をしまっておく文字列領域の大きさ(この場合、300)と、BASICが使用するメモリの上限(この場合、&HD000)を設定することができます。文字列領域の大きさは、メモリの許す限りの値まで指定できます。省略したときは200になります。また、メモリの上限は&H831F〜&HF380の範囲で指定できます。しかし、Disk BASICなどのワークエリアを壊さないように注意しなければなりません。メモリの上限をを設定するときは、文字列領域の大きさを省略できません。メモリの上限については、「4.2 ユーザーエリアの詳細」を参照して下さい。
FRE
カセットテープのプログラムをロードします。
CLOAD[<ファイルスペック>]
CLOAD "TEST"
カセットテープにCSAVEでセーブされたプログラムをロードします。
CLOADが実行されると、<ファイルスペック>で指定されたファイル名のプログラムをカセットテープ上で探します。探している最中に別のプログラムを見つけると「Skip:ファイル名」と画面に表示され、指定されたプログラムが見つかると「Found:ファイル名」と表示してロードを開始します。
CLOADの後ろに指定するファイル名を省略することもできます。省略したときは、CLOADが実行されて最初にみつけたプログラム(CSAVEでセーブされたもの)をロードします。CLOAD命令を実行すると、そのときメモリ上にあったプログラムは無くなってしまうので注意してください。また、CLOADで、SAVE命令によってセーブされたプログラムをロードすることはできません。
CSAVE、
LOAD
カセットテープのプログラムとメモリ上のプログラムを比較します。
CLOAD?[<ファイルスペック>]
CLOAD? "TEST"
メモリ上にあるプログラム(LIST命令で画面に表示されるもの)と、カセットテープにセーブされたプログラムが同じかどうか調べます。同じであれば「Ok」と表示され、違っていると「Veriffy error」と表示されます。CLOAD命令は、普通CSAVE命令を実行した後に、セーブが正しく行われたかどうかを確認するために使われます。
CLOAD?の後ろに指定するファイル名を省略することもできます。省略したときは、CLOAD?が実行されて最初に見つけたプログラム(CSAVEでセーブされたもの)を比較します。
CSAVE、LOAD
ファイルを閉じます。
CLOSE [[#]<ファイル番号>[,[#]<ファイル番号>]・・・]
CLOSE #1
<ファイル番号>に対応するファイルを閉じます。指定した<ファイル番号>は、以後のOPEN文で指定することができるようになります。また、いったん閉じたファイルをもう一度開くときには、他のファイルが使っていない<ファイル番号>ならば、どの<ファイル番号>でも指定することができます。
CLOSEでは、<ファイル番号>を複数指定することにより、一度に複数のファイルを閉じることができます。また<ファイル番号>を省略すると、そのとき開いているファイルをすべて閉じます。
閉じたファイルに対しては、再びOPEN文で開くまで入出力を行うことはできません。CLOSE文は、ファイルが出力用にオープンされていた場合には、バッファに残っていたデータの掃き出しを行うので、ファイルへの出力処理を正しく終了するためには、必ずCLOSE文を実行しなくてはなりません。
END文、NEW文を実行すると、自動的にすべてのファイルが閉じられますが、STOP文はファイルを閉じないので注意する必要があります。
OPEN、END、NEW
画面に表示されている文字や絵を消します。
CLS
CLS
CLSは、KEY ON指定で表示されているファンクションキーの内容を除いて、文字、点、線、絵など画面に表示されているものをすべて消します。
また、CLSが実行されると、テキスト画面の場合、カーソルは画面一番上の左端に移動しますがグラフィック画面ではLP(最終参照点)は変化しません。
CLSは漢字モードでは使用できません。(Illegal function callになる)。漢字モードで画面を消すときはCALL CLS命令を使います。
COLOR、CALL CLS
画面の色を指定します。書式1以外は全てMSX2以降専用です。
COLOR[<前景色>][,<背景色>][,<周辺色>]
COLOR=(<パレット番号>,<Rコード>,<Gコード>,<Bコード>)
COLOR=RESTORE
COLOR[=NEW]
COLOR 1,5,8
色は、それぞれ以下の0〜15(SCREEN6では0〜3)までの値で指定します。
| 0 | 透明(周辺色と同じ色) | | 8 | 赤 |
| 1 | 黒 | | 9 | 明るい赤 |
| 2 | 緑 | | 10 | 黄 |
| 3 | 明るい緑 | | 11 | 明るい黄 |
| 4 | 暗い青 | | 12 | 暗い緑 |
| 5 | 明るい青 | | 13 | 紫 |
| 6 | 暗い赤 | | 14 | 灰 |
| 7 | 水色 | | 15 | 白 |
電源投入時には、COLORは「COLOR 15,4,7」に設定され、SCREEN文を実行したときには、カラーパレットは上記のように設定されています。
SCREEN 8以外では、書式2のCOLOR=を使ってこれらの色を512色の中から選んで自由に設定することができます。
なお、プログラム中でグラフィック画面を指定すると、それまでテキストモードで使われていた色がそのまま使われています。
SCREEN 8の色は、0〜255が使えます。
00000000 8ビットの色コード
GGGRRRBB Green、Red、Blueの各ビット
例えば、明るい緑は&B11100000(=224)、暗い紫なら&B00000101(=5)などとなります。
SCREEN 10では0〜15、SCREEN 11、12では0〜255が使えます。SCREEN 10ではYJK/RGB混在モードのRGB部分のみの指定なので、SCREEN 7以下のカラーパレットの指定と全く同じと考えることができます。SCREEN 11以降ではカラーコードはVRAMの値と考えることができますが、YJK方式の性格上これを単純に解釈することはできません。詳しくはV9958のYJKモードに関する記述を参照してください。
| ■ | 前景色 |
| | テキスト画面(SCREEN 0および1のテキストモード)の文字の色や、グラフィック画面の点や線の色です。ただし、グラフィック画面で点や線などを描くときには、各命令で色の指定を行うことができます。各命令で色を指定すると、その指定の方が優先されます。前景色だけを変えるには例えば、次のように指定します。 |
| | COLOR 9 |
| ■ | 背景色 |
| | テキスト画面やグラフィック画面の地の色のことです。テキスト画面では、命令実行後に指定した背景色に変えられます。グラフィック画面では、SCREENかCLSを実行した後に背景色が変えられます。背景色だけを変えるには、例えば、次のように指定します。 |
| | COLOR ,4 |
| ■ | 周辺色 |
| | 画面上下のBASICで使えない部分のことです。周辺色だけを変えるには、例えば、次のように指定します。 |
| | COLOR ,,13 |
10 SCREEN 5
20 COLOR= (0,0,7,7)
SCREEN 6では0〜3、SCREEN 8以外では0〜15のパレットに色を割り当てます。上の例ではパレット0に0、7、7、つまり
&B000 &B111 &B111
RRR GGG BBB (RGB各3ビット、0〜7の値)
の結果として明るい水色を割り当てています。割り当てた後は、書式1にしたがって色を設定します。
初期状態では、書式1で説明したカラー番号とパレット番号が同じになるように設定してあります。
COLOR=RESTORE
VRAM上のパレットテーブルの情報にしたがってパレットを設定します。
COLOR=NEW
パレットを初期状態にセットします。=NEWは省略してもかまいません。
CALL KANJI、CLS、SCREEN、VRAMマップ、V9958
スプライトの1ライン毎の色を決めます。
COLOR SPRITE$(<プレーン番号>)=<文字式>
COLOR SPRITE$(0)=CHR$(1)+CHR$(7)
スプライトの色も実際には、パレット番号で指定します。この例ではプレーン0の1ライン目を黒に、2ライン目を水色にしています。スプライトの1ライン毎に色をつけられるのは、SCREENモード4以降の時だけです。色コードについてはCOLORを参照してください。なお色コードが15を超える場合、上位4ビットは次のような意味を持ちます。
| bit7 | 32ドット左シフト表示。 |
| bit6 | PUT SPRITEを実行したとき連続したプレーンを同時に動かす。このとき重なった部分の色コードはORされて表示され、衝突は検出されない*。 |
| bit5 | 衝突を検出しない。 |
| bit4 | 未使用。 |
- bit6がONのときは表示が複雑になります。詳しくは「第4部 VDP」を参照して下さい。
| すべてのSPRITE$をSTRING$(32,255)とし、スプライト面0が&B00000111(水色)、スプライト面1が&B01001000(bit6がONされた赤)のとき。 |
| 図2.11 bit6がONの時のスプライト |
bit6がONのスプライト面が連続していると、1つのPUT SPRITE命令でそれらを動かすことができます。
SCREEN 8のスプライトだけは次のような16色に固定されます。
表2.7 SCREEN 8のスプライト色
| カラー番号 | 0 | 1 | 2 | 3 | 4 | 5 | 6 | 7 |
| 色 | 黒 | 暗い青 | 暗い赤 | 暗い紫 | 暗い緑 | 暗い水色 | 暗い黄色 | 灰色 |
| カラー番号 | 8 | 9 | 10 | 11 | 12 | 13 | 14 | 15 |
| 色 | 肌色 | 青 | 赤 | 紫 | 緑 | 水色 | 黄色 | 白 |
COLOR SPRITE(<プレーン番号>)=<式>
COLOR SPRITE(1)=15
プレーン1全体を白にします。
COLOR、
SPRITE
停止したプログラムの実行を再開します。
CONT
CONT
プログラムの実行停止後、「CONT」と入力すると、停止した次の文から実行が再開されます。プログラムの実行停止は、[CTRL]+[STOP]キー入力やプログラム文中のSTOP文やEND文によるものでなければなりません。またINPUT$関数のキー入力待ちを[CTRL]+[STOP]キーで止めた場合は、CONTはできません。
実行停止中にLIST命令やPRINT命令などを実行することはできますが、プログラムそのものの変更を行ったときは、CONTによる実行の再開はできません。
STOP、
END
ファイルやVRAMの内容、配列をコピーします。書式1以外は全てSCREENモードが5以降で有効なのでMSX2以降専用です。パラメータに<ファイルスペック>を含む書式は全てDisk BASICでのみ有効です。論理演算子としては、AND、OR、XOR、PSET、PRESETが指定可能です。
COPY<ファイルスペック1> [TO <ファイルスペック2>]
COPY (<ソース座標1>)-(<ソース座標2>)[,<ソースページ>] TO (<デスティネーション座標>)[,<デスティネーションページ>][,<論理演算子>]
COPY (<ソース座標1>)-(<ソース座標2>)[,<ソースページ>] TO <ファイルスペックまたは配列名>
COPY <ファイルスペックまたは配列名>[,<方向>] TO (<デスティネーション座標>)[,<デスティネーションページ>][,<論理演算子>]
COPY <配列名> TO <ファイルスペック>
COPY <ファイルスペック> TO <配列名>
COPY SCREEN [<モード>]
COPY "A:SAMPLE.DAT" TO "SAMPLE.BAK"
<ファイルスペック1>を<ファイルスペック2>で指定したドライブへ、指定したファイル名でコピーします。このCOPYコマンドはディスク装置間のみで有効です。
指定の方法は4種類あります。
| ■ | <ファイルスペック1>だけを指定した場合 |
| | COPY "B:SAMPLE.DAT" |
| | この場合、SAMPLE.DATは、カレントドライブに同じ名前(SAMPLE.DAT)でコピーされます。 |
| ■ | <ファイルスペック2>でドライブ名だけを指定した場合 |
| | COPY "A:SAMPLE.DAT" TO "B:" |
| | この場合、SAMPLE.DATは、ドライブBに同じ名前でコピーされます。 |
| ■ | <ファイルスペック2>でファイル名だけを指定した場合 |
| | COPY "B:SAMPLE.DAT" TO "SAMPLE.BAK" |
| | この場合、SAMPLE.DATは、カレントドライブにSAMPLE.BAKという名前でコピーされます。 |
| ■ | <ファイルスペック2>でドライブ名とファイル名とを指定した場合 |
| | COPY "A:SAMPLE.DAT" TO "B:SAMPLE.BAK" |
| | この場合、SAMPLE.DATは、ドライブBにSAMPLE.BAKという名前でコピーされます。 |
10 SCREEN 5
20 COPY(10,10)-(100,120),1 TO (30,30),0,XOR
VRAM上の長方形の領域を他の領域にコピーします。ページを省略した場合はそれぞれアクティブページとみなされます。論理演算子を省略した場合はPSETとみなされます。
COPY命令で画面範囲外にコピーした場合、スプライトが表示されてしまうことがあります。例えば、
COPY(0,0)-(255,39) TO (0,211)
を実行すると画面データをスプライトなどのデータエリアに書いてしまうので、スプライトのゴミが表示されてしまいます。VDP(V9938、V9958)はハードウェアスクロールの機能を持っており、COPY文では、その機能を十分生かすために画面表示範囲外に画面データをコピーできるようになっています。したがって、画面表示範囲外に画面データをコピーするときには、スプライトをVDP命令で消して下さい。VDPレジスタのR#8のbit1を1にすると、スプライトの表示が禁止されます。具体的には、以下の命令を実行します。
VDP(9)=VDP(9) OR 2
10 SCREEN 8
20 DIM B%(327)
30 COPY(100,100)-(120,130),0 TO B%
VRAM上の長方形の領域の内容を配列やファイルにコピーします。配列の場合は必要な大きさ以上のものを確保しておかなければなりません。必要なバイト数Nは次のように計算されます。
N=INT(X*Y/K+5)
ただしXは横、Yは縦のドット数、Kは定数で、
| SCREEN 5と7では2 |
| SCREEN 6では4 |
| SCREEN 8以降では1 |
として求め、次に配列の型によって
| 整数型 | (N+1)\2 |
| 単精度型 | (N+3)\4 |
| 倍精度型 | (N+7)\8 |
として最低限必要な要素数が得られます。文例3のケースでは
N=INT((120-100+1)*(130-100+1)/1+5):N=656
(N+1)\2=328
からDIM B%(327)となります。
10 SCREEN 7
20 COPY "TEST",1 TO (100,100),1,AND
ファイルまたは配列の内容を画面に転送します。方向はデータを書き込む向きで、
| 0 | 左上から右下 |
| 1 | 右上から左下 |
| 2 | 左下から右上 |
| 3 | 右下から左上 |
のどれかです。
10 DIM A%(100)
20 COPY A% TO "TEST"
配列の内容をファイルにセーブします。
10 DIM A%(100)
20 COPY "TEST" TO A%
ファイルから配列に内容をコピーしてきます。ファイルはもともと書式3や書式5で作ったものでなければならず、配列は十分な大きさでなければなりません。
10 SCREEN 8
20 COPY SCREEN
外部ビデオ信号をデジタル化し、VRAMに送ります。<モード>は0なら通常で、1ならインタレースモードです。この機能は画像取り込み装置がつながっている場合にのみ有効です。どのスクリーンでどのモードで取り込みができるかはその取り込み装置の性能に依存します。
SET PAGE、
LINE
<数式>の余弦(コサイン)を計算します。
COS(<数式>)
PRINT COS(3.14159)
【表示】-.99999999999649
メモリ上にあるプログラムをカセットテープにセーブします。
CSAVE<ファイル名>[,<ボーレート>]
CSAVE "TEST"
メモリ上にあるプログラム(LIST命令で画面に表示されるもの)を、カセットテープに保存します。
ファイル名の後ろに次のように指定すれば、セーブするときの早さを指定することができます。指定できるのは1か2です。
CSAVE "TEST",1
2と指定すると1の倍の速さでセーブされますが、カセットレコーダの性能によってはうまくセーブできないことがあります。このセーブの速さは、SCREEN命令でも指定でき、CSAVEで省略されたときには、SCREEN命令の指定が使われます。
うまくセーブされたかどうかは、CLOAD?命令で確認してください。セーブされたプログラムは、CLOAD命令を使ってロードすることができます。
CSAVEとSAVEとの違いについては、SAVE命令を参照してください。
CLOAD、
CLOAD?、
SAVE
<数式>の値を単精度実数に変換します。
CSNG(<数式>)
PRINT CSNG(123.45678)
【表示】123.456
テキスト画面のカーソルの行位置を返します。
CSRLIN
A=CSRLIN
CSRLINは、現在カーソルが何行目にあるのかを、一番上の行を0とした値で調べます。
CSRLINは、テキスト画面でのみ使うことができます。
POS
文字列を数値データに変換した値を返します。
CVI(<2バイト文字列>)
CVS(<4バイト文字列>)
CVD(<8バイト文字列>)
PRINT CVI(A$)
ディスク上のランダムファイルから読み込んだ数値データは文字型になっているため、これらの関数を使って数値型に変換しなければなりません。CVIは2文字(2バイト=16ビット)の文字列を整数値に、CVSは4文字の文字列を単精度実数値に、CVDは8文字の文字列を倍精度実数値にそれぞれ変換します。
この変換は、例えば、CVIの場合、次のように行われます。
A$="90"の場合、すなわちA$=CHR$(&H39)+CHR$(&H30)の場合には、CVI(A$)の値は、キャラクターコードを数値データとみなし、&H3039(=12345)となります。
CVS、CVDの場合は、各キャラクターコードを正規化された浮動小数点形式の数値データとみなします。
READ文で読み込むためのデータをプログラム中に用意します。
DATA<定数>[,<定数>・・・]
10 READ A,B
20 DATA 1,2
<定数>は文字型か数値型で、READ文でそのデータを読み込む変数の型と一致していなければなりません。この例では数値型の変数AおよびBに、それぞれ1と2という数値が代入されます。
DATA文中のデータは、1行に収まる範囲内でいくつでもカンマで区切って記述することができます。DATA文中のコロン(:)は引用符に囲まれていない限りマルチステートメントの区切りと解釈されます。DATA文はREAD文によって読み込まれない限り何の働きもしません。
READ、
RESTORE
計算式を定義します。
<名前>[<引数>[,<引数>[,<引数>・・・])]=<関数の定義式>
10 DEF FN A(X)=X*X*3.14
20 FOR I=10 TO 20 STEP 5
30 PRINT FN A(I)
40 NEXT
【表示】314
706.5
1256
10行で円の面積を出す計算式をFN A(X)として定義し、その式を30行でIという変数を使って値を変えながら呼び出しています。
DEF FNは、名前(上の場合A)で、計算式を定義しておくことができます。名前は英字で始まる2文字以内の英数字でつけます。名前の次にカッコで囲んだ変数(上の場合X)を指定して、計算式(上の場合X*X*3.14)を定義します。カッコ内の変数と計算式の中の変数は対応しています。
定義した計算式は「FN 名前(変数)」という形で呼び出せます。定義を行ったときの変数は仮のものなので、呼び出すときにはカッコ内でそのときどきで必要な変数(上の場合I)に変えて指定することができます。
変数の型を宣言します。
DEFINT <文字の範囲>[,<文字の範囲>・・・]
DEFSNG <文字の範囲>[,<文字の範囲>・・・]
DEFDBL <文字の範囲>[,<文字の範囲>・・・]
DEFSTR <文字の範囲>[,<文字の範囲>・・・]
10 DEFINT A,B
20 DEFSTR C-E
30 A=3.12:B=0.33
40 C="3.12":D="0.33":E="ABC"
50 PRINT A,B
60 PRINT C,D,E
【表示】 3 0
3.12 0.33 ABC
この例では変数A、Bを整数型に、変数C、D、Eを文字型に宣言しています。変数の指定は、英字1字(例 A)あるいは英字1字-英字1字(例 A-Z)という形で行います。型は以下のように設定されます。
DEFINT 整数型
DEFSNG 単精度実数型
DEFDBL 倍精度実数型
DEFSTR 文字型
型宣言が行われていない変数は、すべて倍精度実数とみなされます。また、DEF命令での型宣言よりも、型宣言文字での指定の方が優先されます。
CLEAR
機械語プログラムの実行開始番地を指定します。
DEF USR[<番号>]=<開始番地>
DEF USR2=&HE000
USRを使って呼び出す機械語プログラムの、実行開始番地(&HE000)を指定します。DEF USRの次には、複数の機械語プログラムを使うときに区別するための番号(2)を付けます。指定できるのは、0から9までの値です。
CLEAR、
USR、「
5章 マシン語とのリンク」
指定されたプログラム行を削除します。
DELETE<行番号の範囲>
DELETE 50-100
行番号の指定の方法によって、さまざまな形の削除が行えます。以下に、その例を示します。
DELETE 10
行番号10の行を削除します。
DELETE -100
プログラムの先頭から行番号100までの行を削除します。
LIST、MERGE、NEW、RENUM
配列変数を使うことを宣言し、それをメモリ領域に割り当てます。
DIM<変数名>(<添字の最大値>[,<添字の最大値>・・・])
DIM A(11),B%(100),C$(2,3)
DIMは、使用する配列変数の最大値を設定し、同時にメモリ上にその配列の領域を確保します。設定できる最小の値は0,最大の値はメモリ容量が許す範囲です。設定を行わない場合は、値は10(要素数は添字0〜10で11個)とみなされます。
不要になった配列変数は、ERASE命令で削除できます。また、宣言してある配列変数は、CLEAR命令かERASE命令を実行しないと再宣言できません。
ERASE、
CLEAR
グラフィック画面に図形を描きます。
DRAW<文字式>
10 SCREEN 2
20 A$="A0C15S4BM150,80L40D12R8U6R24D6R8U12"
30 B$="BM134,86F12D8L32U8E12"
40 C$="C8BM132,92L4G4D4F4R4E4U4H4"
50 DRAW "XA$;":DRAW "XB$;"
60 DRAW XC$
70 GOTO 70
【表示】☏
各文字変数に代入された文字式が、50行の指定で実行されて、画面に電話器が描かれます。
DRAWでの指定は次のような形で行います。
DRAW "文字式"
DRAW 文字変数
DRAW "X文字変数;"
文字式は、線を描くための情報で記号と数値でできていて、DRAWに続けて引用符で囲んで指定します。文字変数を使って指定するときは、あらかじめその文字変数に、線を描くための情報(文字式)を代入しておきます。文字変数を用いるときには、"X文字変数;"と指定しても(50行)、単に文字変数だけ指定しても(60行)、結果は同じです。
指定する記号には、移動、回転、色、サイズの4種類のものがあります。
表2.8 DRAW文の指定一覧
| 記号 | 数値 | 意 味 | 例 | 備考 |
移 動 命 令 | U | 距離 | 上へ移動 | U10 | 距離は画面の1点を単位とする(単位はサイズ命令で変更可能)斜め方向と上下左右方向で同じ距離を指定しても、画面上での実際の移動距離は異なる。 |
| D | 〃 | 下 〃 | D5 |
| L | 〃 | 左 〃 | L8 |
| R | 〃 | 右 〃 | R12 |
| E | 〃 | 右上 〃 | E7 |
| F | 〃 | 右下 〃 | F20 |
| G | 〃 | 左下 〃 | G15 |
| H | 〃 | 左上 〃 | H40 |
| M | 座標 (X,Y) | (X,Y)まで描画 | M100,100 | Xの前に+か-をつけると相対座標指定 |
| B | なし | 移動のみ | BM50,50 | U〜Mまでの記号につけて用いる。 |
| N | なし | LP移動しない | NL10 | U〜Mまでの記号につけて用いる。 |
回 転 命 令 | A | 0〜3 | 90度単位で回転 | A1U12L4D12 | 0〜270度の回転。指定し直すまで有効。 |
色 命 令 | C | 0〜255 | 色指定 | C8D10 | 色コードの範囲は画面モードによる。 |
サ イ ズ 命 令 | S | 1〜255 | 移動距離の単位 | S20U12L4D12 | 省略値は4で、これが画面1ドット分。 |
■数値変数の指定
なお、次の形式で数値変数も指定できます。
DRAW "=変数名;"
例えば
10 SCREEN 2
20 A=10:B=120
30 DRAW "BM=A;,=B;U20"
40 GOTO 40
というプログラムは(100,120)の位置まで線を引かずに移動し、そこから上に20点分の線を引くというものです。
COLOR
フロッピーディスクの残り容量をクラスタ単位で返します。
DSKF(<ドライブ番号>)
PRINT DSKF(1)
<ドライブ番号>で指定されたフロッピーディスクの残り容量をクラスタ単位で返します。1クラスタは以下の通りです。
| メディア | サイズ |
| フロッピーディスク | 1024バイト |
| RAMディスク* | 512バイト(2Mバイトまで) |
| 1024バイト(2M〜4Mバイト) |
| ハードディスク | 可変〔ハードディスクの初期化(領域確保)のとき、指定する領域の大きさにより1Kバイト、2Kバイト、4Kバイト、8Kバイト、16Kバイト、32Kバイト、64Kバイトから選択する。〕 |
- MSX-DOS2のRAMDISKコマンドで設定するもの。
プログラムを終了します。
END
10 PRINT "ハルガ"
20 END
30 PRINT "コナイ"
40 END
END命令はプログラムを終了させます。プログラム内にいくつ置いてもかまいません。
また、プログラムの最後のEND(この場合、40行)は省略してもかまいません。
上の例では、20行にENDがあるので、その後の行は実行されず、「コナイ」は表示されません。
ファイルが終了したかどうかを調べます。
EOF(<ファイル番号>)
IF EOF(1) THEN CLOSE1
EOFは、ファイル番号で指定されたファイルが終わったかどうか調べるもので、終わっていればー1を、まだ途中であれば0を結果として返します。EOFに続くカッコ内の数値は、指定したファイルのファイル番号で、OPEN命令で指定されているものと対応しています。調べるファイルは、OPEN命令のINPUTモードで開かれていなければなりません。
OPEN、
INPUT#
配列変数を削除します。
ERASE<配列変数名>[,<配列変数名>・・・]
ERASE A
DIMで指定した配列変数を削除し、割り当てられたメモリを使えるようにします。
DIM
エラーコードやエラーの起こった行番号を調べます。
ERR
ERL
10 ON ERROR GOTO 40
20 A%=A%+10
30 GOTO 20
40 IF ERR<>6 THEN 80
50 PRINT ERL;"ギョウデエラーハッセイ"
60 A%=0:PRINT "ショリシマシタ"
70 RESUME
80 ON ERROR GOTO 0
40行で発生したエラーコードが6かどうかの判定を行い、6なら50行でエラーの発生した行番号を表示し、60行でエラーに対する処理を行っています。
このように、ERLやERRを用いると、エラーが発生したとき、エラーの起こった行番号(ERL)やエラーコード(ERR)を知ることが出来ます。
ERLやERRは普通、ON ERROR GOTO命令でジャンプするエラー処理の操作で使われます。ダイレクトモードでエラーが発生したときには、ERLの値は65535となります。
ON ERROR GOTO、
ERROR
プログラムをエラー状態にします。
ERROR<エラーコード>
ERROR 23
ERRORで0から255までの値を指定することによって、プログラムをエラー状態にすることができます。メッセージが用意されているエラーコードを指定すると、画面に対応するエラーメッセージが表示されます。
エラーコード23、26〜49、60〜255にはメッセージが定義されていないので、ON ERROR GOTO文と併せて独自のエラー処理を行うこともできます。
ON ERROR GOTO、[エラーメッセージ表]
自然対数の底「e」の<数式>乗を計算します。
EXP(<数式>)
PRINT EXP(1)
【表示】2.7182818284588
ランダム入出力バッファ中に変数領域を割り当てます。
FIELD[#]<ファイル番号>,<フィールド幅>AS<文字変数>[,<フィールド幅>AS<文字変数>]・・・
FIELD#1, 15 AS A$, 10 AS B$
<ファイル番号>とはOPEN文で開いたファイルにつけた番号のことで<フィールド幅>とは<文字変数>に割り当てられる文字数のことです。また<文字変数>はランダムファイルをアクセスするとき使われる変数名です。
FIELD文は、GET文によるランダム入出力用バッファへのデータの読み込み、あるいはPUT文によるランダム入出力用バッファからのデータの書き出しを可能にするためにGET、PUT文の前に実行されなければなりません。
例えば、
FIELD1, 15 AS A$, 10 AS B$
では、ランダム入出力用バッファ中の最初の15文字(バイト)をA$という文字変数に割り当て、次の10文字がB$に割り当てられます。
FIELD文は、実際にはランダム入出力用バッファにデータを置くことはせず、これはLSET、RSET文で行われます。
FIELD文で割り当てられる総バイト数は、OPEN時に決めたレコード長を越えることはできません。万一、越えた場合には、「Field overflow」エラーが生じます。
なお、1つのファイル番号に対して、何回かに分けてFIELD文を実行してもかまいません。このとき、以前に実行されたFIELD文も、その効力を保持します。FIELD文は、実行するたびに最初の1文字からバッファを定義するため、同一データに対し複数の領域を定義する効果をもちます。
FIELD文で定義した文字変数は、ランダム入出力用バッファ中の対応するデータを指していますが、FIELD文の実行後に入力関係の文、または代入文の左辺で使用すると、その変数は文字列の記憶領域に移り、ランダム入出力用バッファからは消えてしまうので注意する必要があります。
フロッピーディスクの中のファイル名を表示します。
[L]FILES [<ファイルスペック>]
FILES "*.BAS"
LFILES "B:"
<ファイルスペック>で指定されたファイルのファイル名を表示します。指定ファイルがフロッピーディスク中になければ、「File not found」エラーが生じます。
<ファイルスペック>が省略された場合は、現在選択されているディスクドライブ中の全ファイル名を表示します。
指定するファイル名には、疑問符(?)を含むことができ、ファイル名や、拡張子中の1文字の代わりをすることができます。また、ファイル名、拡張子の文字中にアスタリスク(*)を用いると、任意のファイル名、または拡張子の代わりとすることができます。
<ファイルスペック>で、ディスクドライブが指定されていれば、そのディスクドライブ中の指定ファイルが出力され、そうでないときは、現在選択されているディスクドライブ(カレントドライブ)が使用されます。
LFILESは出力先がプリンタであることを除き、FILESとまったく同じです。
<数式>の値の小数点以下を取り去った値を計算します。
FIX(<数式>)
PRINT FIX(-1.2)
【表示】-1
<数式>の値が正のときはINTと同じですが、負のときは以下のようになります。
| 式 | 結果 | 意味 |
| FIX(-1.2) | -1 | 小数点以下切り捨て |
| INT(-1.2) | -2 | -1.2を超えてない最大の整数 |
FORからNEXTまでの間で指定された操作を、指定された回数だけ繰り返します。
FOR<変数名>=<初期値>TO<終値>[STEP<増分>]
10 FOR I=0 TO 10 STEP 2
20 PRINT I
30 PRINT "ループ"
40 NEXT I
50 END
FORで繰り返しの回数を指定し、FORとNEXTの間の操作をその回数だけ繰り返し行います。FORの次に「I=0」の形で、繰り返しの初期値(0)を設定します。TOの次で繰り返しの最終値(10)を設定します。最後にSTEPに続けて初期値と最終値との間の増分(2)を指定します。
プログラムの実行がNEXT(40行)まで来ると、変数Iが増分だけ増やされます。そして、最終値を越えていなければFOR(10行)に戻ります。したがって、初期値が最終値よりも大きく設定されているときも、FOR文からNEXT文までのプログラムは一度実行されます。
このプログラムでは、10行の指定で、Iが0、2、4、6、8、10と増えますので、20行と30行は6回実行され、「ループ」は変数Iの値とともに6回表示されます。Iが最終値10と同じになったところでプログラムの実行はFOR〜NEXTから出て、NEXTの次の行に移ります。
FOR〜NEXTのSTEP以下は省略することができます。省略したときは増分は+1になります。
メモリの未使用領域の大きさを返します。
FRE(<引数>)
PRINT FRE(0)
引数が数値の場合は、BASICが使っていないメモリの大きさ(ユーザーエリアの未使用領域)がバイト数で返されます。引数は、数値であれば何でもかまいません。
PRINT FRE("A")
引数が文字列の場合は、まず文字領域の整理が行われ、それから未使用の文字領域の大きさがバイト数で出されます。この引数は、文字列であれば何でも(空文字でも)かまいません。
CLEAR、[メモリマップ]
ランダムファイルから、ランダム入出力用バッファに1レコードを読み込みます。
GET [#]<ファイル番号>[,<レコード番号>]
GET #1,1
<ファイル番号>は、そのファイルをOPEN文によって開いたときに指定した番号です。<レコード番号>が省略された場合には、直前のGET、PUT文で参照されたレコードの次のレコードがバッファに読み込まれます。レコード番号として指定可能な最大の数は、4,294,967,295です。
<文字変数>に現在の日付を代入します。
GET DATE <文字変数>[,A]
GET DATE A$
現在の日付を指定した<文字変数>に代入します。オプションのAを付けると、アラームの設定された日付が代入されます。日付は、「85/04/03」のように年月日がスラッシュで区切られ、月日が1桁の場合は04のように2桁となります。
<文字変数>に現在の時刻を代入します。
GET TIME <文字変数>[,A]
GET TIME T$
現在の時刻を指定した<文字変数>に代入します。オプションのAを付けると、アラームの設定された時刻が代入されます。時刻は、「11:20:03」のように時分秒がコロン(:)で区切られ、時刻が1桁の場合は03のように2桁となります。
指定したサブルーチンを呼び出します。
GOSUB<行番号>
10 GOSUB 30
20 END
30 PRINT "ココカラサブルーチン"
40 PLAY "CDE"
50 PRINT "GOSUBノツギノギョウヘモドル"
60 RETURN
GOUSUB命令で指定した行で始まるサブルーチンを呼び出します。呼び出されたサブルーチンは、RETURN命令によってGOSUBの次の文または行に戻ります。サブルーチンとは、GOSUBで指定する行から、RETURNの行までの独立した1つのプログラムです。
RETURN、
GOTO
指定した行にジャンプします。
GOTO<行番号>
10 PRINT "10ギョウデス":GOTO 30
20 PRINT "20ギョウデス":END
30 PRINT "30ギョウデス"
40 GOTO 20
【表示】10ギョウデス
30ギョウデス
20ギョウデス
10行で、30行に飛ぶように指定しているので、20行のEND命令を飛び越して30行が実行されます。そのあと、40行から20行にジャンプして、プログラムは終了します。
ON GOTO、
ON GOSUB、
GOSUB
<数式>の数値を16進数の文字列に変換します。
HEX$(<数式>)
PRINT HEX$(12)
【表示】C
VAL、BIN$、OCT$、STR$
条件判断を行い、その結果に応じた操作を行います。
IF<条件>THEN<文または行番号>[ELSE<文または行番号>]
IF<条件>GOTO<行番号>[ELSE<文または行番号>]
10 A=A+1
20 PRINT A
30 IF A=20 THEN PRINT "ハタチ" ELSE 10
40 END
IFに続けて条件を指定します。その条件が満たされた(0以外の値を取る)ときはTHEN以下の指定が実行され、条件が満たされない(0を値として取る)ときはELSE以下の指定が実行されます。
ELSE以下の指定は省略することができます。その場合、条件が満たされなかったときは次の行が実行されます。
THEN、ELSEの後ろの指定は、文でも行番号でもかまいません。THENの後ろに行番号を指定する場合、THENの代わりにGOTOを使って、IF〜GOTO〜ELSEという形にすることもできます。
条件には、以下のような比較演算子と論理演算子とが使えます。論理演算子は、複数の条件を指定するときに用います。
比較演算は条件が成立したときには「-1」、成立しないときには「0」を値として返します。
表2.9 比較演算
| 比較演算子 | 意味 | 例 |
| 式1=式2 | 式1が式2と等しい | IF A$="y" |
| 式1<>式2 | 式1が式2と等しくない | IF A<>0 |
| 式1<式2 | 式1が式2より小さい | IF A<10 |
| 式1>式2 | 式1が式2より大きい | IF A>B |
式1<=式2 (式1=<式2) | 式1が式2と等しいか、小さい | IF A<=B+1 |
式1>=式2 (式1=>式2) | 式1が式2と等しいか、大きい | IF A>="Z" |
表2.10 論理演算
| 論理演算子 | 例 | 意味 |
| NOT | IF NOT (A=1) | Aが1でなければTHEN以下を実行 |
| AND | IF A=0 AND B=3 | Aが0でBが3のときのみTHEN以下を実行 |
| OR | IF A<0 OR B=0 | Aが0より小さいか、Bが0のときにTHEN以下を実行 |
キーが押されていればその文字を、押されていなければ空文字(ヌル)を返します。
INKEY$
10 A$=INKEY$
20 IF A$='"' THEN 10
30 PRINT A$;"=";HEX$(ASC(A$))
40 GOTO 10
このプログラムを実行すると、キーボードから打ち込まれた文字と、その文字のアスキーコードが画面に表示されます。
INKEY$は、[CTRL]+[C]と[CTRL]+[STOP]以外のコントロール文字も読み取ります。
INPUT、
LINE INPUT、
INPUT$、[キャラクターコード表]
指定した入力ポートからデータを獲得します。
INP(<ポート番号>)
A=INP(15)
カッコ内のポート番号(15)で指定された入力ポートから1バイトのデータを読み取り、その値をAに代入します。ポート番号に関しては、巻末の「I/Oマップ」を参照して下さい。
INP関数は、ハードウェアと非常に密着した関数で、他のMSX機種では返す値が違う場合もあります。MSXの互換性を維持するため、広く公表するプログラムには使用しないでください。
OUT、
WAIT
キーボードから入力されるデータを指定した変数へ代入します。
INPUT["<プロンプト文>";]<変数名>[,<変数名>・・・]
10 INPUT"データ";A
20 PRINT A * A:GOTO 10
INPUT命令を実行すると、疑問符(?)が画面に表示され、プログラムはキーボードからのデータ入力待ちになります。何か数値を入力するとその数値は?に続いて画面に表示され、その値が指定された変数Aに代入されます。
引用符(")で囲まれた文字列(上の例の場合"データ")は、プロンプト文と呼ばれるもので、これを指定していれば、?の前にその文字列が表示されて、メッセージの役割を果たします。
変数は、カンマ(,)で区切って複数個指定することもできます。この場合、入力するデータもカンマで区切って、変数の数だけ入力しなければなりません。入力するデータの個数が足りないと、「??」と表示されて入力待ちとなり、個数が多いと「?Extra ignored」と表示され、余分に入力されたデータは無視されます。また、対応する変数の型とデータの型は、一致していなければなりません。型が違っていた場合には、「Redo from start」と表示されて再び入力待ちとなります。
ファイルからデータを読み込みます。
INPUT #<ファイル番号>,<変数>[,<変数>・・・]
INPUT #1,A,B
あらかじめOPEN文でINPUTモードを指定して開いておいたファイルからデータを読み込み、変数にセットします。INPUT #文はデータを読み込む対象がファイルであることを除けば、INPUT文とほぼ同じです。
<ファイル番号>は、OPEN文で指定した番号です。
INPUT #文で読み込むデータは、PRINT #文で書き出した各データと対応した順に読み込まれます。したがって<変数>の型はファイルから入力するデータの型と対応していなくてはなりません。
ファイル中のデータのうち、先に続くスペース、ラインフィードは無視され、スペース、ラインフィード以外の最初の文字がデータの始まりとされます。データは、スペース、キャリッジリターン、ラインフィード、カンマによって区切られていなければなりません。
ファイル中のデータが文字列型の場合には、最初の文字が引用符(")であると、その文字型データは、最初の引数から次の引用符までの間に読み込まれた文字で構成されれているとみなされます。したがって、引用符で囲まれた文字列中には、引用符を文字として入れることはできません。最初の文字が引用符以外のときは、文字列は、囲まれていないものとして扱われ、カンマ、キャリッジリターン、ラインフィード、または255文字の読み込み終了によって区切られます。数値、または文字型データの読み込み中に、ファイルの終わり(EOF)に達したときは、そのデータ項目はそこで区切られます。
INPUT、
OPEN、
PRINT #
指定されたファイルから指定された長さの文字を獲得します。
INPUT$(<文字列>[,[#]<ファイル番号>])
WD$=INPUT$(6,#2)
<ファイル番号>で指定されたファイルから<文字数>分の文字列を読み出します。
INPUT$は、[CTRL]+[STOP]、[CTRL]+[C]を除くすべての文字をそのまま読み出すので、INPUT文やLINE INPUT文では入力することのできないラインフィードコードやリターンコードも入力することができます。
#のあとの数値は、読み出すファイルのファイル番号で、OPEN命令で指定されたものと対応しています。ファイル番号が省略された場合には、キーボードから入力されたデータを読み出しますが、INPUT命令と異なり、入力された文字は画面に表示されません。
[CTRL]+[STOP]でこの入力を中断した場合、CONTは実行できません。
カッコ内の最初の数値は、読み出す文字数を指定しています。キーボードからの入力を読み出す場合、INPUT$は指定された文字数の文字が入力されるのを待ち続けますが、すでにキーボードバッファに入力済みのデータがあるときには、バッファの中の文字から先に読み出します。
OPEN、
INPUT、
LINE INPUT
ある文字列の中から指定された文字列を捜し、見つかった位置を返します。
INSTR([<数式>,]<文字列1>,<文字列2>)
10 A$="SUPER MSX"
20 PRINT INSTR(A$,"M")
30 END
【表示】7
引数の最初の文字列(A$)の中から、2番目の文字列(「M」)をさがします。この例の場合、「M」はA$の頭から数えて7番目にあたるので、結果は7になります。
指定された文字列が見つからなかったときは、結果は0になります。また、INSTR(6,A$,"M")のように、最初に数値を入れて、さがし始める位置を指定することもできます。
<数式>以下の最大の整数を返します。
INT(<数式>)
PRINT INT(-1.2)
【表示】-2
<数式>の値が正のときはFIXと同じですが、負のときは異なります。FIXを参照して下さい。
ON INTERVAL GOSUB命令の設定を実行するかどうかを決定します。
INTERVAL ON
INTERVAL OFF
INTERVAL STOP
ON INTERVAL=100 GOSUB 100:INTERVAL ON
INTERVAL ONは、ON INTERVAL GOSUBの設定を実行するように指定し、以後、指定した時間ごとにサブルーチンにジャンプします。INTERVAL OFFは、設定によるジャンプを禁止します。INTERVAL STOPは、設定によるジャンプを一時止め、後でINTERVAL ONが指定されると直ちにジャンプを実行します。
ON INTERVAL GOSUB
ファンクションキーの内容を定義します。
KEY<キー番号>,<文字列>
KEY 1,"LOAD"
数値はファンクションキーの番号に対応させるため、1〜10までの値でなければなりません。定義できる文字列は、最大15文字までの文字およびコントロール文字です(コントロール文字は、CHR$を使って表現します)。一度定義したファンクションキーの内容は、あらたに定義し直すか、一旦電源を切って再び電源を入れるまで変わりませんので注意してください。
CHR$、
KEY LIST、
KEY ON、
KEY OFF
ファンクションキーの内容を画面に表示します。
KEY LIST
KEY LIST
[F1]〜[F10]までのすべてのファンクションキーの内容を画面に表示します。
電源投入時には、ファンクションキーの内容は以下のように設定されています。
| F1 | "color" |
| F2 | "auto" |
| F3 | "goto" |
| F4 | "list" |
| F5 | "run"+CHR$(13) |
| F6 | "color 15,4,7"+CHR$(13) |
| F7 | "cload"+CHR$(34) (MSX2+では"load"+CHR$(34)) |
| F8 | "cont"+CHR$(13) |
| F9 | "list."+CHR$(13)+CHR$(31)+CHR$(31) |
| F10 | CHR$(12)+"run"+CHR$(13) |
KEY、KEY ON、KEY OFF
ファンクションキーが押されたときに特別な処理を行うかどうかを決定します。
KEY(<キー番号>)ON
KEY(<キー番号>)OFF
KEY(<キー番号>)STOP
10 ON KEY GOSUB 40,60
20 KEY(1) ON:KEY(2) ON
30 GOTO 30
40 PRINT "F1ガオサレマシタ"
50 KEY(1) STOP:RETURN
60 PRINT "F2ガオサレマシタ"
70 RETURN
この命令は、ON KEY GOSUBによって定義された処理のサブルーチンの実行を許可するか(ON)、禁止するか(OFF)、一時停止するか(STOP)を決定します。
カッコ内の数値は、ファンクションキーのキー番号に対応しています。例えば、KEY(1) ON を実行すると、[F1]を押すごとに、ON KEY GOSUBにより定義されている処理のサブルーチンが呼び出されます。サブルーチンが実行されている間は、KEY(1) STOP が自動的に実行されるので、サブルーチンの実行が終わるまでは、多重にサブルーチンが呼び出されることはありません。KEY(2) OFF を実行すると、[F2]を押しても、用意された処理のサブルーチンは実行されません。KEY(3) STOP を実行すると、[F3]を押しても、用意された処理のサブルーチンは実行されませんが、再びKEY(3) ON を実行することによって、処理が実行されます。この命令は、KEY(3) ON の状態でのみ有効です。
上のプログラムでは、[F1]に関して、一旦KEY ONしていますが(20行)、その処理のサブルーチンでKEY STOPしているので(50行)、一度[F1]キーが押されてしまうと、2度目からは「F1ガオサレマシタ」というメッセージは表示されません。
ON KEY GOSUB
ファンクションキーの内容を画面の下部に表示するかしないかを設定します。
KEY ON
KEY OFF
KEY ON
KEY OFF
KEY ONを実行すると、ファンクションキーの内容が画面の最下行に表示されます。普通の状態では[F1]〜[F5]までが、シフトキーを押しているときは[F6]〜[F10]までが表示されます。
KEY OFFを実行すると、ファンクションキーの表示がとりやめられます。KEY ON/OFF は SET SCREEN 命令により、初期状態を登録することができます。
KEY、
KEY LIST
ファイルを消去します。
KILL<ファイルスペック>
KILL "A:SAMPLE.BAK"
<ファイルスペック>で指定したファイルを消去します。ファイルスペックの指定には、ワイルドカード(?や*)を使うことができますが予想外のファイルまで消去してしまわないよう十分注意が必要です。また、ファイルスペック中で、ドライブ名が指定されてない場合は、自動的に現在選択されているドライブ(カレントドライブ)とみなされます。開いているファイルに対してKILLコマンドを実行すると、「File still open」エラーとなります。
<文字列>の左側から指定された数の文字列を返します。
LEFT$(<文字式>,<数式>)
10 A$="SUPER HOME COMPUTER"
20 B$=LEFT$(A$,5)
30 PRINT B$:END
【表示】SUPER
与えられた文字列(A$)の左側から、数値(5)で指定された数の文字を取り出します。
指定した数が、文字列の総文字数より大きいときは、文字列がそのまま取り出されます。
<文字式>で指定された文字列の総文字数を返します。
LEN(<文字式>)
10 A$="SUPER HOME COMPUTER"
20 PRINT LEN(A$)
30 END
【表示】19
LEN はコントロールコードや空白も文字として数えます。
変数に値を代入します。
[LET]<変数名>=<式>
10 LET A=10
20 B = 20
30 PRINT A;B
【表示】10 20
代入するものは、文字列でも数値でも構いません。LETは省略できるので、普通は使いません。
グラフィック画面に数値や四角を描きます。
LINE[ [STEP](X1,Y1)]-[STEP](X2,Y2)[,<カラーコード>][,B[F]][,<論理演算子>]
10 COLOR 15,4,7:SCREEN 2
20 LINE(88,56)-(168,136),6,BF
30 LINE(128,76)-(108,116),15
40 LINE -STEP(40,-25),15
50 LINE -STEP(-40,0),15
60 LINE -STEP(40,25),15
70 LINE -(128,-76),15
80 GOTO 80
10行でグラフィック画面を指定してから、20行で赤く塗りつぶされた四角を描き、30行から70行でその四角の中に星を描いています。
LINEは、(X1,Y1)で指定した視点と(X2,Y2)で指定した終点とを結ぶ直線を引きます。X軸方向には、SCREEN 2〜5および8以降では255、SCREEN 6と7は511まで、Y軸方向には、SCREEN 2〜4では191、SCREEN 5以降では211までありますので、0からこの値の範囲の点を指定すると、画面に線が描かれます。
色を指定すると、指定した色で線が引かれます。省略した場合は、COLORで指定している前景色が使われます。色と指定する値との対応については、COLORを参照してください。
<カラーコード>の後にBを指定すると、(X1,Y1)から(X2,Y2)を結ぶ線を対角線にした四角が描かれます。BFを指定したときには、四角の中が指定された色で塗りつぶされます(20行参照)。LINEの最後に<論理演算子>を指定すると、LINEの色を次のように操作することができます。ただしこの指定ができるのは、SCREEN 5以降に限られます。
Cを指定色、SCをLINEの下になる色としたときは、
| AND | C AND SC |
| OR | C OR SC |
| XOR | NOT(C) AND SC |
| PSET | C |
| PRESET | NOT(C) |
| TAND | C AND SC(C=0ならC=SC) |
| TOR | C OR SC(C=0ならC=SC) |
| TXOR | NOT(C) AND SC(C=0ならC=SC) |
| TPSET | C(C=0ならC=SC) |
| TPRESET | NOT(C) (C=0ならC=SC) |
が実際の色となります。
(X1,Y1)を省略して-(X2,Y2)だけが指定されると、最終参照点から(X2,Y2)までを結んだ線が引かれます(70行参照)。最終参照点というのは、線や点などを描くのに1番最後に指定された点のことです。
もう1つのLINEの指定は、STEPを用いたものです。STEPをつけて指定された点は、最終参照点からカッコの中で指定した値の分だけ移動した点を示します。例えば、最終参照点が(100,100)であったとすると、STEP(20,-30)というのは、(120,70)の点を指すことになります。したがって、STEPを用いて引かれる線は、最終参照点とそこからの距離によって指定される点とを結んだものになります。(40、50、60行参照)。
80行で80行自身にジャンプしているのは、グラフィック画面では、プログラムの実行が終わると直ちにテキスト画面に移ってしまうからです。これについてはSCREENを参照してください。
SCREEN、
COLOR
キーボードから入力される1行全体の文字列をそのまま文字変数に代入します。
LINE INPUT["<プロンプト文>";]<文字型変数名>
10 LINE INPUT"データ";A$
20 PRINT A$
30 GOTO 10
LINE INPUT命令を実行すると、プログラムはキーボードからの入力待ちの状態になります。このとき、疑問符(?)は表示されません。以降、何かデータを入力すると、リターンキーを押すまでに入力された文字データが画面に表示され、それがそのまま文字型変数に代入されます。キーボードから入力できる文字列の長さは、254文字以内です。また、LINE INPUT命令では、カンマ(,)や引用符(")もデータとして入力できます。
なお、INPUT命令同様、引用符(")を用いてプロンプト文を指定することができます。
INPUT
1行単位のデータをファイルから文字列変数へ読み込みます。
LINE INPUT #<ファイル番号>,<文字列型変数名>
LINE INPUT #1,A$
あらかじめOPEN文でINPUTモードを指定して開いておいたファイルからキャリッジリターンコード+ラインフィードコードで区切られている1行単位(255文字以内)のデータを指定した文字変数に読み込みます。
SAVE文でアスキー形式のプログラムファイルを作成した場合、一行一行はキャリッジリターンコード(CHR$(13))とラインフィードコード(CHR$(10))とで区切られて書き出されています。また、PRINT#文で作成したファイルにはPRINT#文を実行するごとに数値や文字列の並びがキャリッジリターンコード+ラインフィードコードで区切られて書き出されています。LINE INPUT#文はこれらのファイルからキャリッジリターンコード+ラインフィードコードにはさまれているデータを読み込むときに使います。
<ファイル番号>はOPEN文で指定した番号です。
OPEN、CLOSE、PRINT#、LINE INPUT
メモリにあるプログラムを画面に表示、プリンタに印刷します。
[L]LIST[<行番号1>][-[<行番号2>]]
LIST 100-200
行番号1と同じか行番号1以上で最も近い番号の行から、行番号2または行番号2以下で最も近い番号の行までのプログラムを画面に表示(LLISTはプリンタに印刷)します。
LIST
プログラムの先頭から最後までが表示されます。
LIST 50
行番号50の行のみ表示されます。
LIST -100
プログラムの先頭から100行目までが表示されます。
LIST 200-
プログラムの200行目から最後までが表示されます。
LISTの機能を中断したいときは[STOP]キーを押して下さい。[STOP]キーをもう一度押せば表示を再開します。また、LISTの機能を終了したいときは、[CTRL]+[STOP]キーを押して下さい。
LISTの代わりにLLISTを用いれば、プログラムをプリンタに印刷することができます。
プログラムをメモリ上に読み込みます(ロードする)。
LOAD<ファイルスペック>[,R]
LOAD "A:TEST"
LOADコマンドは<ファイルスペック>で指定したプログラムをメモリ上にロードします。LOAD文を実行すると、LOAD文実行前にメモリ上にあったプログラムは消去されます。また、すべての開いているファイルは閉じられ、変数の値は初期化されます。
<ファイルスペック>のデバイス名を省略すると、カレントドライブからロードします。
また、ファイル名はカセットファイルに対して用いる時のみ省略でき、この場合はLOAD"CAS:"とします。ディスクファイルの場合はプログラムのセーブ形式が、バイナリでもアスキーでもかまいませんが、カセットファイルではアスキー形式でセーブしたものに限られます。カセット上のバイナリ形式のプログラム(CSAVEしたもの)はCLOADでのみロードすることができます。
Rオプションをつけるとファイルは開いたままで、プログラムをロード後、ただちに実行を開始します。
LOADは、指定されたファイルを見つけてプログラムのロードを開始するまでは、メモリ上のプログラムを保存しています。
SAVE、
CLOAD
ファイル中の現在の位置を返します。
LOC(<ファイル番号>)
IF LOC(1) > 50 THEN STOP
ランダムファイルを指定したときは、LOC関数は、最後に読んだり書いたりしたレコード番号を値として返します。ただし、オープン直後はLOC関数の値は0になっています。
シーケンシャルファイルを指定したときは、そのファイルがオープンされてから読み出されたり書き込まれたデータのバイト数を返します(ただし256バイトを1単位とする)。ファイルをシーケンシャル入力モードでオープンした場合は、BASICは最初のセクタを自動的に読むので、そのファイルを読む前でもLOC関数の値は256となります。
テキスト画面のカーソル位置を指定します。
LOCATE[<X座標>][,<Y座標>][,<カーソルスイッチ>]
LOCATE 10,12
カーソルを指定する位置へ移動します。(10,12)なら、画面の左側から11桁目、上から13行目の位置を意味しています(0から指定するため)。LOCATE命令でカーソル位置を指定してから、PRINTやINPUTを実行すると、その位置に文字や?が表示されます。指定された位置が画面の範囲を超えていると、横、縦とも、それを超えない最大の値に設定し直されます。
<カーソルスイッチ>は、0なら入力待ちの時のみカーソルを表示、0以外なら常に表示となります。LOCATEは、テキスト画面および漢字グラフィックモードでのみ使うことができます。
指定されたファイルの大きさを返します。
LOF(<ファイル番号>)
IF NM%>LOF(1) THEN PRINT"INVALID ENTRY"
指定されたファイルの実際の大きさをバイト単位で返します。
<数式>の自然対数を返します。
LOG(<数式>)
PRINT LOG(10)
【表示】2.302585092994
プリンタのヘッドの位置を調べます。
LPOS(<式>)
A=LPOS(0)
現在のプリンタのヘッド位置を調べ、その結果をAに代入します。LPOSによって得られる値は、プリンタバッファ上のプリンタヘッドの位置なので、必ずしも実際の(物理的な)プリンタヘッドの位置とは限りません。カッコ内の数値は形式的なものなので、何であっても構いません。
LPRINT、
WIDTH
プリンタに文字列や数値を印刷します。
LPRINT[<式>・・・]
10 A$="ABC":A=123
20 LPRINT A$,A
30 LPRINT 45"DEF"
LPRINTに続けて指定された数値(この場合、45)や文字列(DEF)をプリンタに出力します。また、数値変数(A)や文字変数(A$)が指定されると、それらの変数に代入されている数値や文字列がプリンタに出力されます。
LPRINT命令は、出力先がプリンタであることを除けば、その機能や使い方はPRINT命令と全く同じですので、そちらを参照して下さい。
PRINT、
PRINT USING、
LPRINT USING
文字列や数値を指定した書式でプリンタに印刷します。
LPRINT USING<書式>;<式>・・・
LPRINT USINGを実行すると、引用符(")で囲まれた書式にしたがって、指定された文字列や数値が編集され、その結果がプリンタに出力されます。
LPRINT USING命令は、出力先がプリンタであることを除けば、その機能や使い方はPRINT USING命令と全く同じですので、そちらを参照して下さい。
PRINT USING、
LPRINT
ランダム入出力用バッファにデータを転送します(PUTコマンドのための準備)。
LSET<文字型変数>=<文字式>
RSET<文字型変数>=<文字式>
LSET D$=MKI$(D)
<文字式>の文字が、FIELD文で指定された文字より短い場合は、LSET文では左詰め、RSETでは右詰めでフィールド内を埋め、余分な所は空白で満たされます。逆にFIELD文での割り当てより長い場合は、LSET文、RSET文両方とも文字列の右側が失われます。また、数値データを扱うときは、あらかじめそれらを文字型データに変換しておかねばなりません。それらについては、MKI$、MKS$、MKD$の各関数を参照して下さい。
LSET文、RSET文はFIELD文で定義されていない文字型変数についても、そのフィールド内で左詰めないし右詰めをすることができます。これは、プリント出力の構成に際して利用することができます。
使用するファイルの数を定義します。
MAXFILES=<ファイル数>
MAXFILES=3
OPEN文で開いて使用するファイルの数を定義します。以降、指定したファイルを同時に開いて使用することができます。定義しないときは、MAXFILES=1に設定されています。<ファイル数>は0〜15の範囲を持つ式で、ファイル1個について267バイトのファイルコントロールブロック領域が確保されます。MAXFILES文を実行すると、変数がすべて初期化され、現在オープンしているファイルはクローズされます。また、以前の変数の型宣言などは無効になります。
CLEAR、
OPEN
アスキー形式で保存されているプログラムをメモリ上のプログラムにマージ(混合)します。
MERGE<ファイルスペック>
MERGE "CAS:TEST"
メモリ上のプログラムに<ファイルスペック>で指定したプログラムファイルを混合して1つのプログラムにし、メモリ上に置きます。<ファイルスペック>で指定するファイルはSAVE"",A文を使ってアスキー形式でセーブされていなければなりません。そうでない場合には、ドライブ名を指定していればエラーとなり、CAS:を指定していればテープが回り続けます。<ファイルスペック>のデバイス名を省略すると、カレントドライブが使用されます。ファイル中のプログラムと、メモリ中のプログラムに同一行番号があった場合には、ファイル中の行でメモリ中の行を置き換えます。MERGEコマンドは実行を終了すると、コマンドレベルにもどります。
SAVE、
LOAD
文字列の中から指定された数の文字列を取り出します。
MID$(<文字列>,<式1>[,<式2>])
10 A$="SUPER HOME COMPUTER"
20 PRINT MID$(A$,7,4)
30 END
【表示】HOME
文字列(A$)の左から数えて7番目の文字から、4つの文字を取り出します。取り出したい文字数(この場合は4)が省略されたときや、文字列の残りの文字数よりも大きいときは、指定した位置以降のすべての文字列が取り出されます。
LEFT$、
RIGHT$、
MID$��
文字変数の一部を他の文字列と置き換えます。
MID$(<文字変数>,<式1>[,<式2>])=<文字列>
10 A$="SUPER HOME COMPUTER"
20 MID$(A$,7,4)="ホーム"
30 PRINT A$:END
【表示】SUPER ホーム COMPUTER
文字列(A$)の左から数えて7番目から4文字を、右辺の文字列("ホーム")と置き換えます。この代入文を実行しても、もとの文字列の長さは変わりません。また、文字数(4)を省略すると<文字列>の文字数と見なされます。
MID$��
各数値を内部表現に対応したキャラクタコードに変換します。
MKI$ (<整数表記>)
MKS$ (<単精度表記>)
MKD$ (<倍精度表記>)
RSET A$=MKI$(123)
ランダムファイルでは、文字データしか扱えないので、数値データは文字型データに変換してディスクに書き込み、読み出す際は逆に文字型データを数値型データに変換します。MKI$は整数値を2バイトの文字列に、MKS$は単精度数値を4バイトの文字列に、そしてMKD$は倍精度数値を8バイトの文字列にそれぞれ変換します。
数値から文字への変換は数値が持つ内部表現(2進数表現)の値をそのままそれに対応するキャラクターコードにすることによって行われます。この逆の動作をする関数としてCVI、CVS、CVD関数が用意されています。
カセットレコーダのモーターをON、OFFします。
MOTOR[ONまたはOFF]
MOTOR ON
リモート端子のあるカセットレコーダを接続したときに、モーターのON、OFFを行って、カセットテープの早送り、巻き戻しができるようにします。MOTOR ONと指定するとモーターがONになり、MOTOR OFFとするとOFFになります。MOTORとだけ指定すると、現在モーターがONならOFFに、OFFならONになります。
ファイルの名前を変更します。
NAME<ファイルスペック>AS<ファイル名>
NAME"TEST.BAS" AS "TEMP.BAS"
変更しようとするファイルは存在しているものでなければなりません。また、付けようとする名前と同じファイルは存在していてはなりません。ドライブ名を省略すると、カレントドライブ(現在選択されているドライブ)が選択されます。NAMEコマンドが実行されると、そのファイルの名前は変更されますが、ファイルの存在する位置や、占有する大きさなどは変化しません。
メモリにあるプログラムを削除し、すべての変数を初期化します。
NEW
NEW
NEWを実行すると、メモリにあるプログラムはすべて削除され、定義されている変数はすべて初期化され、開かれているファイルはすべて閉じられます。
DELETE、
ERASE
<数式>の数値を8進数の文字列に変換します。
OCT$(<数式>)
PRINT OCT$(100)
【表示】144
BIN$、HEX$
エラーが起こったときにジャンプする行を指定します。
ON ERROR GOTO <行番号>
10 ON ERROR GOTO 60
20 A$=INKEY$
30 IF A$="Y" THEN 80
40 A%=A%+100
50 GOTO 20
60 PRINT "ショリ":A%=0
70 RESUME
80 ON ERROR GOTO 0
10行で、エラーが起こったとき60行にジャンプするように指定してあるので、40行のA%が32767を超えて「OverFlow」エラーが起きると60行にジャンプし、A%に0を代入します。
あらかじめ、エラーを処理する部分をプログラム中に入力しておき、プログラムの最初にON ERROR GOTOでその部分の最初の行を指定しておけば、エラーが起きたときに、エラー処理用の指定が実行されます。エラー処理用の指定の最後にはRESUME命令を置くと、エラー処理を終了させ、もとのプログラムを再開させることができます(70行参照)。
ON ERROR GOTO 命令は、他のON ERROR GOTO命令、RUN、CLEAR、NEWが実行されるまで有効ですので、そのままプログラムを終了すると、ダイレクトモードでタイプミなどをしても、再びエラー処理用の行へジャンプし、プログラムが実行されていしまいます。したがってプログラムの終了直前には、ON ERROR GOTOの指定を無効にする、ON ERROR GOTO 0を実行するようにしてください(80行参照)。
RESUME、
ERL、
ERROR
<式>で指定されたいずれかの行にジャンプします。
ON<式>GOSUB<行番号>[,<行番号>・・・]
ON<式>GOTO<行番号>[,<行番号>・・・]
10 INPUT "1 カ 2 ヲ オシテクダサイ";A
20 ON A GOTO 100,200
30 GOTO 10
100 PRINT "100ギョウニジャンプシマシタ":END
200 PRINT "200ギョウニジャンプシマシタ":END
10 INPUT "1 カ 2 ヲ オシテクダサイ";A
20 ON A GOSUB 100,200
30 GOTO 10
100 PRINT "100ギョウニジャンプシマシタ":RETURN
200 PRINT "200ギョウニジャンプシマシタ":RETURN
ON と GOTO、あるいはON と GOSUBの間の値(A)に応じて、GOTO、GOSUBの後ろで指定した行にジャンプします。ON GOTOは指定した行にジャンプし、ON GOSUBは指定した行で始まるサブルーチンにジャンプします。(GOSUB参照)。
GOTO、GOSUBの後ろの指定は、左から1、2、3、・・・という数に対応していて、例えば、上の例では、1が押されれば100行に、2が押されれば200行にジャンプします。
対応する行番号がないとき(上の例では0や3以上の数値を入力した場合)は、次の命令が実行されます。負の数が指定されたときは、Illegal function callエラーとなります。
GOTO、GOSUB
指定した時間ごとにサブルーチンの呼び出しを行うように設定します。
ON INTERVAL=<時間>GOSUB<行番号>
10 ON INTERVAL=600 GOSUB 40
20 INTERVAL ON
30 GOTO 30
40 PRINT"*";
50 RETURN
INTERVAL で指定する時間は、1から65535までの数値で、単位は1/60秒です。ON INTERVAL GOSUB命令は、設定を行うだけです。設定後にINTERVAL ONを指定して初めて、指定した時間がた経つとサブルーチンにジャンプします。サブルーチンから戻るには、RETURN命令を使います。また、RETURNに戻り先の行番号を指定することもできます。
RETURN命令が実行されるまでは、INTERVAL STOPが実行されたときと同じ状態になっているので、多重にインターバル割り込みがかかることはありません。
上のプログラムは10秒ごとに「*」を表示するものです。10行で、ON INTERVALで指定した時間(600)ごとに、GOSUBで指定された行(40行)にジャンプするように設定しています。
INTERVAL ON、
INTERVAL OFF、
INTERVAL STOP
ファンクションキーが押されたときにジャンプする行を指定します。
ON KEY GOSUB[<行番号>][,<行番号>・・・]
10 ON A GOSUB 40,60
20 KEY(1)ON:KEY(2)ON
30 GOTO 30
40 PRINT "F1ガ オサレマシタ"
50 RETURN
60 PRINT "F2ガ オサレマシタ"
70 RETURN
ファンクションキーが押されたときに、呼び出すサブルーチンの行番号を指定します。
ON KEY GOSUBに続く行番号(40と60)が、実際に処理を行うサブルーチンの先頭行で、指定されたファンクションキー([F1]と[F2])が押されたときには、プログラムの実行はここに移ります。
行番号の並びの順序は、ファンクションキーのキー番号に対応しています。ファンクションキーは[F1]から[F10]まであるので、最大10個の行番号が並べられます。
呼び出されたサブルーチンは、GOSUB命令同様、RETURN命令によってジャンプした次の行に戻ります。また、RETURNに戻り先の行番号を指定することもできます。ただし、この命令は、ファンクションキーが押されたときの処理の定義を行うだけで、これだけでは処理は実行されません。上のプログラムでも、20行が実行されて、初めて40行と60行が実行されています。詳しくは、KEY(n) ON/OFF/STOPを参照して下さい。
KEY(n) ON、KEY(n) OFF、KEY(n) STOP
スプライトパターンが重なったときにジャンプする行を指定します。
ON SPRITE GOSUB<行番号>
10 SCREEN 1,1
20 SPRITE$(0)=STRING$(8,CHR$(&B11111111))
30 ON SPRITE GOSUB 90
40 PUT SPRITE 0,(100,100),1,0
50 SPRITE ON
60 X=255
70 PUT SPRITE 1,(X,100),6,0
80 X=X-1:GOTO 70
90 REM SUB
100 X=255
110 RETURN
30行で、スプライトのパターンが重なったときには、90行にジャンプするように指定しています。
ON SPRITE GOSUBを実行しておき、SPRITE ONを実行すると、画面上でスプライトパターンが重なったときに、ON SPRITE GOSUBで指定した行(90)へジャンプします。ジャンプした行以降で、スプライトが重なったときの処理を行ったあとは、RETURNで元の行へ戻ります。また、RETURNに戻り先の行番号を指定することもできます。
なお、SCREEN 4以降のスプライトで特殊なカラーコードを持つものは衝突しても割り込みを起こしません。詳しくはCOLOR SPRITE文を参照してください。
SPRITE ON、SPRITE OFF、SPRITE STOP
[CTRL]+[STOP]キーが押されたときにジャンプする行を指定します。
ON STOP GOSUB<行番号>
ON STOP GOSUB 100
[CTRL]+[STOP]キーが押されると、プログラムの実行は100行以降に移ります。ON STOP GOSUBは、[CTRL]+[STOP]キーが押されたときに、分岐するサブルーチンの行番号を指定するものです。ON KEY GOSUBに続く行番号(この場合、100)が、実際に処理を行うサブルーチンの先頭行になります。呼び出されたサブルーチンは、GOSUB命令同様、RETURN命令によってジャンプした次の行に戻ります。また、RETURNに戻り先の行番号を指定することもできます。ON KEY GOSUBの説明を参照して下さい。
ON KEY GOSUB、
STOP ON、
STOP OFF、
STOP STOP
ジョイスティックのトリガボタンが押されたときにジャンプする行を指定します。
ON STRIG GOSUB<行番号>[,<行番号>・・・]
ON STRIG GOSUB,100,200
ポート1に接続されているジョイスティックのトリガボタン1が押されたらプログラムの実行を100行以降に移し、ポート2に接続されているジョイスティックのトリガボタン1が押されたらプログラムの実行を200行以降に移します。
この命令は、ジョイスティックのトリガボタンが押されたときに、分岐するサブルーチンの行番号を指定するものです。ON STRIG GOSUBに続く行番号(この場合、100と200)が、実際に処理を行うサブルーチンの先頭行で、指定されたトリガボタンが押されたときには、プログラムの実行はここに移ります。
行番号は最大5個まで指定することができ、左側から順に以下のトリガボタンと対応しています。
| 行番号 | 意味 |
| 1番目 | キーボードのスペースキー |
| 2番目 | ポート1に接続されているジョイスティックのトリガボタン1 |
| 3番目 | ポート2に接続されているジョイスティックのトリガボタン1 |
| 4番目 | ポート1に接続されているジョイスティックのトリガボタン2 |
| 5番目 | ポート2に接続されているジョイスティックのトリガボタン2 |
ただし、ジョイスティックによっては、トリガボタン2のないものもあります。
呼び出されたサブルーチンは、GOSUB命令同様、RETURN命令によってジャンプした次の行に戻ります。また、RETURNに戻り先の行番号を指定することもできます。ただし、この命令は、ジョイスティックのトリガボタンが押されたときの処理の定義を行うだけで、これだけでは処理は実行されません。STRIG(n) ON/OFF/STOP を参照して下さい。
STRIG(n) ON、STRIG(n) OFF、STRIG(n) STOP、ON KEY GOSUB
ファイルを開きます。
OPEN<ファイルスペック>[FOR<モード>]AS#<ファイル番号>[LEN=<レコード長>]
OPEN "SAMPLE.DAT" FOR OUTPUT AS #1
OPEN文は、ファイルを使用するにあたってバッファエリアを割り当て、アクセスモードを決定します。一度ファイルをオープンすると、以降は、<ファイル番号>でデータのやりとりを行います。以下の命令や関数を使用する前には、あらかじめOPEN文を実行しておくことが必要です。
| EOF | FIELD |
| GET | INPUT# |
| INPUT$(n,#m) | LINE INPUT# |
| LOC | LOF |
| PRINT# | PRINT#USING |
| PUT | VARPTR(#n) |
<ファイルスペック>でドライブ名を省略したときは、現在のディスクドライブが使用されます。
<モード>はファイルに対するアクセスモードを決定するもので、次の4種類があります。
| FOR INPUT | 既存のシーケンシャルファイルから入力を行う。 |
| FOR OUTPUT | 新しくシーケンシャルファイルを作り出力を行う。 |
| FOR APPEND | 既存のシーケンシャルファイルに新たなデータを追加出力する。 |
| <モード>省略 | ランダムファイルに対して入出力を行う。 |
<ファイル番号>は、1から15までの値を用いることができますが、MAXFILES文で指定した数を超えて指定することはできません。また、既にオープンされているファイルが使用している番号を用いることはできません。
シーケンシャル入力モードおよび追加モードでは、指定されたファイルが存在しないと、「File not found」エラーとなります。シーケンシャル出力モードでは、常に指定された名前のファイルを新しく作り、同一名のファイルがあった場合にはそのファイルは削除されます。ランダム入出力モードでファイルが存在しない場合には新たに作られます。<レコード長>は、ランダム入出力モードでファイルをオープンしたときの、レコード長を設定するものです。これは1から256の範囲で、省略した場合は256に設定されます。シーケンシャル入力、あるいはランダム入出力モードを指定する場合には、1つのファイルを複数のOPEN文により開くことができます。この場合、異なるファイル番号により指定することになりますが、シーケンシャル出力モードを指定する場合には、1つのファイルを複数のOPEN文により開くことはできません。
■ファイルの指定
OPENに続く<ファイルスペック>で、そのファイルを操作する場所とファイル名を指定します。ディスクファイル以外では次の7つがあります。
| カセットレコーダ | “CAS:ファイル名(6文字以内)”と指定する |
| メモリディスク | “MEM:ファイル名”と指定する |
| ディスプレイのテキスト画面 | “CRT:”と指定する |
| ディスプレイのグラフィック画面 | “GRP:”と指定する |
| プリンタ | “LPT:”と指定する |
| コンソールデバイス | “CON:”と指定する |
| ヌルデバイス | “NUL:”と指定する |
コンソールデバイスはキーボードからの読み込み、画面への書き込みに使用します。例えば、
COPY "TEST.DOC" TO "CON"
とすると、TEST.DOCの内容を画面に表示します。
ヌルデバイスは実際には何もしません。出力文字は無視され、入力は常にエンドオブファイル([CTRL]+[Z])となります。
ファイル名が必要なのは、ディスクファイルおよび、CAS:やMEM:だけです。
CLOSE、INPUT#、PRINT#、MAXFILES、INPUT$、EOF
指定した出力ポートにデータを送ります。
OUT<ポート番号>,<式>
OUT &H22,&H80
&H22のポート番号で指定された出力ポートへ、&H80というデータを送ります。ポート番号に関しては、I/Oマップを参照してください。
OUTは、ハードウェアと非常に密着した命令で、各々のMSXで異なる動作をする場合があります。MSXの互換性を維持するため、広く公表するプログラムには使用しないでください。
INP
タッチパネルの状態を調べます。
PAD(<数式>)
X=PAD(1)
ポート1に接続されたタッチパネルが押されていたら、その点のX座標を変数Xに代入します。
PADに続くカッコ内には、0から19まで値が入ります。PAD命令を実行すると、指定によって、以下の結果が返されます。
| 数値 | 意味 | 出される値 |
| 0、4 | タブレットのデータが有効かどうかを調べる | 有効=-1 |
| | 無効=0 |
| 1、5 | タブレットが押されている点のX座標を調べる | X座標 |
| 2、6 | タブレットが押されている点のY座標を調べる | Y座標 |
| 3、7 | タブレット上のスイッチが押されているかどうかを調べる | 押されている=-1 |
| | 押されていない=0 |
| *8 | ライトペンのデータが有効かどうかを調べる | 有効=-1 |
| | 無効=0 |
| *9 | ライトペンのX座標を調べる | X座標 |
| *10 | ライトペンのY座標を調べる | Y座標 |
| *11 | ライトペンのスイッチが押されているかどうかを調べる | 押されている=-1 |
| | 押されていない=0 |
| *12、*16 | マウスまたはトラックボールのデータを与える | 常に-1 |
| *13、*17 | マウスまたはトラックボールのX座標を調べる | X座標 |
| *14、*18 | マウスまたはトラックボールのY座標を調べる | Y座標 |
| *15、*19 | マウスまたはトラックボールのデータを与える | 常に0 |
0〜3または12〜15はポート1に接続された装置を、4〜7または16〜19はポート2に接続された装置を調べます。ただし、*のついた装置(8〜19)はMSX BASIC ver 2.0以降で有効です。
どの周辺装置も座標を調べる前にはそのデータが有効かどうかを確認しなければなりません。それぞれPAD(0)または(4)、PAD(8)、PAD(12)またはPAD(16)を実行して、その値が-1であったら他のデータを調べて下さい。
STRIG、PDL
グラフィック画面の、指定された境界色でかこまれた部分を指定された色で塗りつぶします。
PAINT[STEP](X,Y)[,<領域色>][,<境界色>]
10 SCREEN 3
20 CIRCLE(128,96),50,11
30 PAINT(128,96),6,11
40 GOTO 40
(128,96)を中心点にして、黄色で書かれた円の中を赤で塗ります。
PAINTの指定は次の形で行います。
PAINT(X,Y)、領域色、境界色
PAINTは(X,Y)で指定した位置を含む境界色で囲まれた領域を、領域色で塗りつぶします。色の指定については、COLORを参照してください。
(X,Y)の指定はSTEPを使って行うこともできます。STEPについては、LINEを参照してください。
境界色はSCREEN 3および5以上でだけ使えます。SCREEN 2や4では、領域色と同じ色で囲まれた領域が、領域色で指定した色で塗られます。例えば、上の例をSCREEN 2で行うと次のようになります。
10 SCREEN 2
20 CIRCLE(128,96),50,11
30 PAINT(128,96),11
40 GOTO 40
領域色の指定を省略すると、COLORで指定している前景色が使われます。境界色の指定を省略すると、領域色で指定したものと同じ色が使われます。PAINTを実行したときに、指定した境界色(SCREEN 2の場合には領域色)で囲まれた領域がないと、画面一面が指定した領域色で塗りつぶされます。
SCREEN、COLOR
パドルの状態を調べます。
PDL(<パドル番号>)
X=PDL(2)
例ではポート2に接続されたパドルの状態を調べ、その結果を変数Xに代入します。
PDLに続くカッコ内には、1から12までの値が入ります。数値が奇数(1、3、5、7、9、11)ならば、ポート1に接続されたパドルが指定され、偶数(2、4、6、8、10、12)ならば、ポート2に接続されたパドルが指定されます。
PDL命令を実行すると、パドルの状態がその回転の度合いによって、0〜255の間の値で得られます。
PAD、STRIG
メモリ上に指定された番地の内容を読み出します。
PEEK(<番地>)
A=PEEK(&HA000)
例ではカッコ内で指定された番地(&HA000)のメモリの内容が、数値としてAに代入されます。読み込み番地は、-32768〜65535の範囲の数値で指定します(数値が負の場合は、その値に65536を加えれば実際の番地を知ることができます)。読み込まれるデータは、0〜255の値を持つ数値です。
POKE、メモリマップ
音楽を演奏します。
PLAY<文字式1>[,<文字式2>][,<文字式3>]
10 PLAY "O4L4T180V8"
20 PLAY "GAGAGGE2"
30 PLAY "EFEFEECR"
40 PLAY "E2CDE2CD"
50 PLAY "EFGGDEDR"
60 PLAY "GAGAGGE2"
70 PLAY "EFEFEECR"
80 PLAY "A2GEGGEC"
90 PLAY "EEDDC2"
指定された記号にしたがって、音楽を演奏します。10行では、演奏のためのテンポ(はやさ)や音量、音階の音域などを指定しています。
文字式は、音楽を演奏するための記号を組み合わせたもので引用符で囲みます。文字変数で指定するときは、その文字変数に演奏用の記号を代入しておきます("X文字変数;")と指定しても、単に文字変数だけを指定しても、結果は変わりません)。記号には音の高さ、音の長さ、速さ(テンポ)、音の大きさ、音色の指定の5種類があります。
PLAYでは、3つのチャンネルを使うことができ、最大3重和音まで出すことができます。文字式1、文字式2、文字式3はそれぞれチャンネル1、2、3に対応しています。文字式に何も指定しなければ、そのチャンネルからは音がでません。
以下で、各記号についての解説を行います。
PLAY "C","E","G"
■音の高さ
| A〜G | 音の高さを音階名で表現する。A〜Gの後ろに#、+をつけると半音上がり、-を付けると半音下がる。 |
| O1〜8 | 音階の音域を1〜8の数値で指定する。初期値はO4。例えば、O5はO4より1オクターブ上の音階を指す。 |
| N0〜96 | 音の高さを0〜96の数値で表現する。N1はO1のC#と同じ高さ、N96はO8のBと同じ。N0はR(休符)と同じ。 |